strudel

table of contents

this page lists the songs i've made using the music live coding environment Strudel , in reverse chronological order ! if the syntax looks unfamiliar , it's because i prefer to use Mondo Notation .

songs

silver fern

play in Strudel

show code 
// @title silver fern @by autumn
mondo` setcps 1.1
$ def fern <g2:major g2:major:pentatonic
            e2:minor d2:major>

$ s [[<rim oh> hh hh]*2, <<[bd ~!4 bd] [bd*3 ~]*2> sd>]
# bank circuitstom # lp 5000 # freq [100 200]

$ n [1 3 [5 [3|7]]]
# sound gm_electric_bass_finger # scale fern
# gain 1.5 # delay .5

$ n <<8 15> [~!4 <15 17> ~] 13 <12 [10 11]>>
# sound piano # scale g2:major
# gain 0.5 # distort 2 # phaser 8

$ n <[1 [3 3] 9] 4 [1 3 [4 9]] 9 [3 4 9 0 ~ 2] 0
     [13 12 11 10 9 8] [6 5 4 3 2 0]>
# sound gm_xylophone # scale fern # transpose 24
# gain .18 # distort 3 # lp 1000 # delay .5`

shimmer

play in Strudel

show code 
// @title shimmer @by autumn
mondo` setcpm 27
$ def shimmer
  <E2:major E2:minor:pentatonic
   <A2:major C2:minor:pentatonic>>

$ n <[0 6 4 5 0 [2 6] 4 5]!3
     [0 6*3 4 5 5*3 ~ 6*5 5]>
# sound jazz # lp <2500 1500> # swing 4

$ n [[1 2 3 4 5 6]
     <[8 9]*3 [9 8]*3
      [8 9 10 12 13 15]
      [14 13 12 10 9 8]*3>]
# sound gm_celesta # scale shimmer
# gain .7 # room 1

$ n <[1 [5 ~ ~] 1 [2 3 4]]!3
     [-2 5 [-5 ~ ~ ~]*5 [8 [7 ~]]!3]>
# sound [gm_piano, (gm_orchestra_hit # hp 500 # lp 2000)]
# scale shimmer # transpose 12
# gain .4 # room <1 1.5 2 [2 5]>

$ n [<5 1 5 <4 7>> ~]
# sound gm_violin # scale shimmer
# gain 2 # lp 1000`